The Designer's Guide Community Forum

The Designer's Guide Community Forum
https://designers-guide.org/forum/YaBB.pl
Simulators >> Circuit Simulators >> a problem in Hspice Simulation
https://designers-guide.org/forum/YaBB.pl?num=1112837677

Message started by James on Apr 6^th, 2005, 6:34pm

Title: a problem in Hspice Simulation
Post by James on Apr 6^th, 2005, 6:34pm

Hi all,

I did parametric sweep in Hspice as following:

.param vctr=0.6
v16 vctr_vco 0 DC=vctr
.TRAN 200ps 100ns sweep vctr 0 1 0.1

the result shows:

**error**: element 0:vctr has been
referenced but not defined id= 9

But I used the same way to simulate another ckt, it OK and didn't encounter this problem.

Any hint on this problem is appreciated.

Best!

Title: Re: a problem in Hspice Simulation
Post by 020170 on Apr 21^st, 2005, 4:48pm

I can help you if you write out your all netlist

Title: Re: a problem in Hspice Simulation
Post by James on Apr 21^st, 2005, 6:15pm

Thank you for your help. The netlist is as following. It's a vco.

.option acct post probe
.protect
.lib 'test.lib' TT
.lib 'test.lib' TT_3V
.unprotect
.PARAM vdd1p8=1.8
.param vctr_para=0.6

*.option acct post probe
*.protect
*.lib 'MS018_v1p2.lib' TT
*.lib 'MS018_v1p2.lib' RES_TT
*.unprotect

.subckt delay_vco avdd1p8v avss1p8v biasn inn inp outn outp
c2 outp outn 3.52e-15
c1 outn avss1p8v 10.5e-15
c0 outp avss1p8v 10.5e-15
mp6 outn outn avdd1p8v avdd1p8v p L=500e-9 W=2.25e-6 AD=1.08e-12 AS=1.08e-12 PD=3.21e-6 PS=3.21e-6 M=3
mp7 outp outp avdd1p8v avdd1p8v p L=500e-9 W=2.25e-6 AD=1.08e-12 AS=1.08e-12 PD=3.21e-6 PS=3.21e-6 M=3
mp28 outp outn avdd1p8v avdd1p8v p L=700e-9 W=1.9e-6 AD=912e-15 AS=912e-15 PD=2.86e-6 PS=2.86e-6 M=1
mp29 outn outp avdd1p8v avdd1p8v p L=700e-9 W=1.9e-6 AD=912e-15 AS=912e-15 PD=2.86e-6 PS=2.86e-6 M=1
mn6 net071 biasn avss1p8v avss1p8v n L=2e-6 W=5e-6 AD=2.4e-12 AS=2.4e-12 PD=5.96e-6 PS=5.96e-6 M=16
mn0 outn inp net071 avss1p8v n L=300e-9 W=4e-6 AD=1.92e-12 AS=1.92e-12 PD=4.96e-6 PS=4.96e-6 M=2
mn1 outp inn net071 avss1p8v n L=300e-9 W=4e-6 AD=1.92e-12 AS=1.92e-12 PD=4.96e-6 PS=4.96e-6 M=2
.ends delay_vco

.subckt vco avdd1p8v avss1p8v end3p3v ibn_10u outn outp vctr
xi6 avdd1p8v avss1p8v biasn net53 net49 net45 net41 delay_vco
xi5 avdd1p8v avss1p8v biasn net64 net66 net53 net49 delay_vco
xi7 avdd1p8v avss1p8v biasn net45 net41 outn outp delay_vco
xi0 avdd1p8v avss1p8v biasn outp outn net64 net66 delay_vco
r0 net0127 net0154 14k
r1 vcm avss1p8v 23.7k
r5 biasp net042 10k
mn2 avss1p8v vcm avss1p8v avss1p8v n L=2e-6 W=12.48e-6 M=50
mn0 biasn biasn avss1p8v avss1p8v n L=2e-6 W=5e-6 M=8
mn1 net0151 net0151 avss1p8v avss1p8v n L=2e-6 W=5e-6 AD=2.4e-12 AS=2.4e-12 PD=5.96e-6 PS=5.96e-6 M=8
mn15 net046 net046 avss1p8v avss1p8v n L=3e-6 W=4e-6 AD=1.92e-12 AS=1.92e-12 PD=4.96e-6 PS=4.96e-6 M=2
mn17 net042 net046 avss1p8v avss1p8v n L=3e-6 W=4e-6 AD=1.92e-12 AS=1.92e-12 PD=4.96e-6 PS=4.96e-6 M=5
mp4 vcm biasp avdd1p8v avdd1p8v p L=1.5e-6 W=10e-6 AD=4.8e-12 AS=4.8e-12 PD=10.96e-6 PS=10.96e-6 M=12
mp1 net0127 biasp avdd1p8v avdd1p8v p L=1.5e-6 W=10e-6 AD=4.8e-12 AS=4.8e-12 PD=10.96e-6 PS=10.96e-6 M=12
mp2 net0151 vctr net0154 avdd1p8v p L=500e-9 W=10e-6 AD=4.8e-12 AS=4.8e-12 PD=10.96e-6 PS=10.96e-6 M=4
mp19 net042 net042 avdd1p8v avdd1p8v p L=1.5e-6 W=10e-6 AD=4.8e-12 AS=4.8e-12 PD=10.96e-6 PS=10.96e-6 M=12
mp8 avdd1p8v biasp avdd1p8v avdd1p8v p L=2e-6 W=10.8e-6 AD=5.184e-12 AS=5.184e-12 PD=11.76e-6 PS=11.76e-6 M=100
mp3 biasn vcm net0127 avdd1p8v p L=500e-9 W=10e-6 AD=4.8e-12 AS=4.8e-12 PD=10.96e-6 PS=10.96e-6 M=4
mp0 net0154 biasp avdd1p8v avdd1p8v p L=1.5e-6 W=10e-6 AD=4.8e-12 AS=4.8e-12 PD=10.96e-6 PS=10.96e-6 M=12
mn18 ibn_10u end3p3v net046 avss1p8v NCH3 L=400e-9 W=4e-6 AD=1.92e-12 AS=1.92e-12 PD=4.96e-6 PS=4.96e-6 M=1
.ends vco

.ic outn_vco=1.8 outp_vco=0.1
iv5 avdd1p8v ibn_10u DC=10e-6
xi0 avdd1p8v avss1p8v end ibn_10u outn_vco outp_vco vctr_vco vco
v0 end 0 DC=3.3
v2 avdd1p8v 0 DC=vdd1p8
v3 avss1p8v 0 DC=0
v16 vctr_vco 0 DC=vctr_para

.TEMP 60
.TRAN 200ps 100ns sweep vctr_para 0 1 0.1

.probe tran v(o1)
.END

The simulation result shows:
**error**: element 0:vctr_para has been
referenced but not defined id= 9

Thanks in advance. This problem has bothered me for a long time.

James

Title: Re: a problem in Hspice Simulation
Post by microant on Apr 24^th, 2005, 8:07pm

hi james
maybe you can change 'tr' instead of 'vctr', in Hspice when use DC/AC/TRAN analysis, the sweep param is not better with the first letter such as 'V', 'I', the hspice will recogenize as a independent voltage or current source.i have meet with the similar problem. you can try it:)
best regards
microant

Title: Re: a problem in Hspice Simulation
Post by James on Apr 25^th, 2005, 5:14am

Microant:

Thanks very much. That's the problem you indicated. After I changed the name of vctr, it worked.