The Designer's Guide Community Forum

The Designer's Guide Community Forum
https://designers-guide.org/forum/YaBB.pl
Design >> Analog Design >> Bidirectional Balun
https://designers-guide.org/forum/YaBB.pl?num=1190617096

Message started by nobody on Sep 23^rd, 2007, 11:58pm

Title: Bidirectional Balun
Post by nobody on Sep 23^rd, 2007, 11:58pm

Hello, all

I have a question about the balun which is listed below and implemented with Hspice.
Is this balun bidirectional ?
I can get the balanced signals 'vp' and 'vn' if 'vd' and 'vc' are known.
However, I can not get the unbalanced signals 'vp' and 'vn' if 'vd' and 'vc' are known.
To get rid of error(1), I add a dummy resistor. But I can not get rid of error (2).

Error messages are :
(1)**error** no input to vccs/vcvs at node 0:vodm defined in subckt 0
(2)**error** inductor/voltage source loop found containing 1:e2 defined in subckt balun

*** Balun
.subckt balun vd vc vp vn
e1 vp vc transformer vd gnd 2
e2 vc vn transformer vd gnd 2
.ends balun
*** CKT
vx+ vx+ 0 pwl(0 0 1n 0 1.01n 250m 1000n 250m 1000.1n -250m 2000n -250m 2000.1n 250m)
vx- vx- 0 pwl(0 0 1n 0 1.01n -250m 1000n -250m 1000.1n 250m 2000n 250m 2000.1n -250m)
Xtest vodm vocm vx+ vx- balun
.op
.tran 0.1n 3000n
.lib 'cmos35.txt' nominal
.end

Title: Re: Bidirectional Balun
Post by simon2 on Oct 10^th, 2007, 8:07am

No. Use:

.SUB Gyrator (Pin Nin Pout Nout)

*---------------------------------------------
* Pin o---o--o--- ----o Pout
* | | |_ |
* Rp | _Ef
* | | | |
* | | | Rs
* | | | |
* | Fr~~~~~Vs
* | | | |
* Nin o---o--o--- ----o Nout
*---------------------------------------------

Rp Pin Nin 10Meg
Ef Pout 5 Pin Nin 1
Rs 5 6 1u
Vs 6 Nout 0
Fr Nin Pin Vs 1
.ENDS Gyrator

which is a simple 1:1 isolation bi-directional transformer. The voltage controlled voltage source implements the "forward" path, whereas the current controlled current source implements the "reverse" path, both are completely independent of the other; a simple explanation is that a voltage applied at the left appears at the right resulting in a current through the load on the right, which is reflected back to the left such that an impedance on the right appears electrically on the left. The input and output common mode levels are completely isolated and the structure works to DC.

For a realistic "balun" use a transformer with one side centre-tapped thus:

*** Centre-tapped 2:1 matching transformer:

.SUBCKT Tx2CT21 (GND PP PCT PN SP SN)

.PARAM Lp=1u n=2 Ll=1n K=0.96 Cw=2p
*---------------------------------------------
* PP o---o-Cl/2--
* | |
* Lp/2 o---o SP
* | |
* PCTo---o Ls
* | |
* Lp/2 o---o SN
* | |
* PN o---o-Cl/2--
*---------------------------------------------

Xoutpp PP PCT SP SN Gyrator1
Xoutpn PCT PN SP SN Gyrator1

Ls S SN {Lp*n^2}
Ll SP S {(1-K)*Lp*n^2}

CPSp PP SP {Cw/2}
CPSn PN SN {Cw/2}

.SUBCKT Gyrator1 1 2 3 4
*---------------------------------------------
* 1 o---o--o--- ----o 3
* | | |_ |
* Rp | _Ef
* | | | |
* | | | Rs
* | | | |
* | Fr~~~~~Vs
* | | | |
* 2 o---o--o--- ----o 4
*---------------------------------------------
Rp 1 2 10Meg
Ef 3 5 1 2 {n}
Rs 5 6 1u
Vs 6 4 0
Fr 2 1 Vs {n}
.ENDS Gyrator1

.ENDS Tx2CT21CT

You will probably have to put the netlists as a text file into Wordpad to view the text "diagrams" properly .... the example is for a Mini-circuits centre-tapped 2:1 balun typically used for an unbalanced 50 ohm line to a balanced 100 ohm line as used in the VHF and lower UHF bands. The syntax is for WinSPICE, you may have to change .subckt to .sub and change the curly brackets { } to single quotes ' ' around the expressions for Hspice and Spectre. Some versions of SPICE may not like the gyrator subcircuit nested inside the transformer sub-circuit. Other versions may not like the n^2, but rather prefer n** or n*n. Notice that n sets the turns ratio and therefore the impedance that will appear from one side to the other.

Title: Re: Bidirectional Balun
Post by Ken Kundert on Oct 10^th, 2007, 9:03am

You can also use the balun described in "A testbench for differential circuits" (http://www.designers-guide.org/Analysis/diff.pdf). They may be a little simpler, and are surely bidirectional.

-Ken