The Designer's Guide Community Forum

The Designer's Guide Community Forum
https://designers-guide.org/forum/YaBB.pl
Simulators >> RF Simulators >> How to simulate noise using Spectre/SpectreRF
https://designers-guide.org/forum/YaBB.pl?num=1080536686

Message started by ayow on Mar 28^th, 2004, 9:04pm

Title: How to simulate noise using Spectre/SpectreRF
Post by ayow on Mar 28^th, 2004, 9:04pm

Hi all,
I would like to simulate noise curve of a MOSFET.
The noise curve should with freq. swept from 0~30MHz
to include 1/f , thermal and shot noise.

Which analysis I can use ? Could you please provide the
example of input.scs ?

Thanks.
Ayow ???

Title: Re: How to simulate noise using Spectre/SpectreRF
Post by Andrew Beckett on Mar 29^th, 2004, 6:13am

Here's a simple example - just put this together for one of my colleagues:

Code:

// Generated for: spectre
// Generated on: Mar 29 11:31:59 2004
// Design library name: mynoise
// Design cell name: test
// Design view name: schematic
simulator lang=spectre
global 0
parameters vg=1 vd=2
include "rfModels.scs"

// Library name: mynoise
// Cell name: test
// View name: schematic
V1 (net1 0) vsource dc=vd type=dc
V0 (net3 0) vsource dc=vg type=dc
M0 (net1 net3 0 net1) nmos301 w=10u l=1u
simulatorOptions options reltol=1e-3 vabstol=1e-6 iabstol=1e-12 temp=27 \
tnom=27 scalem=1.0 scale=1.0 gmin=1e-12 rforce=1 maxnotes=5 maxwarns=5 \
digits=5 cols=80 pivrel=1e-3 ckptclock=1800 \
sensfile="../psf/sens.output"
noise noise start=1 stop=1G dec=10 oprobe=V1 annotate=status
modelParameter info what=models where=rawfile
element info what=inst where=rawfile
outputParameter info what=output where=rawfile
designParamVals info what=parameters where=rawfile
saveOptions options save=allpub

The rfModels.scs is:

Code:

// rf models
model nmos301 mos3 type=n \
vto=0.725 uo=585.0 tox=23.5n nsub=3.27e+16 \
nfs=3.5e+11 vmax=1.6e+05 eta=0.012 kappa=0.13 theta=0.080 \
delta=2.62 xj=0.08u rsh=533.0 \
ld=0.250u cgdo=2.1e-10 cgso=2.1e-10 af=1.0 kf=2.5e-28 \
cj=4.4e-04 mj=0.370 cjsw=3.4e-10 mjsw=0.220 pb=1.100

Note that the models themselves need to have flicker noise enabled (the above simple mos3 model does, because it has af, kf defined).

Essentially you can wire up the device how you want; I'm measuring the noise through id in the V1 voltage source. Because I'm measuring it with a probe of a voltage source, the output will be in A/sqrt(Hz) (or A**2/Hz).

Regards,

Andrew.