Designer’s Guide Community

microant Junior Member Offline Posts: 16 China,SH	how to plot op parameter curve in hspice? Apr 18^th, 2005, 7:20pm Hi everyone, I meet a problem with Avanti Hspice. I want to plot the curve of MOSFET operation point parameter such as gm,cgs,cgtot etc when i run a DC parameter sweep. but it seem that hspice didn't have this function, could anyone give me some advise? thanks and best regrads microant ???
Back to top	IP Logged

020170 New Member Offline Posts: 2	Re: how to plot op parameter curve in hspice? Reply #1 - Apr 21^st, 2005, 4:56pm sorry. i don't know cgs, cgtot. but if you want to know gm in saturation region, I can help you in saturation, gm = root( 2 * K' * W/L * Idsat ) I wish that it was helpful
Back to top	IP Logged

Andrew Beckett Senior Fellow Offline Life, don't talk to me about Life... Posts: 1742 Bracknell, UK	Re: how to plot op parameter curve in hspice? Reply #2 - Apr 21^st, 2005, 9:45pm I remember from many years ago that this was done with the element access functions LVnn() and LXnn() wher nn was a number which determines which parameter to output. This is covered in the HSPICE manual, I'm sure (it was 10 years ago when I used HSPICE, so I'm sure it is now). Regards, Andrew.
Back to top	IP Logged

James Community Member Offline snowfiled Posts: 32	Re: how to plot op parameter curve in hspice? Reply #3 - Apr 22^nd, 2005, 7:15am Plotting Variables Use this template to plot internal variables, such as: i(mn1) i1, i2, i3, or i4 can specify the true branch currents, for each transistor node. LV18(mn6) Total gate capacitance (C-V plot). LX7(mn1) GM gate transconductance. (LX8 specifies GDS, and LX9 specifies GMB).
Back to top	James IP Logged

James

Community Member

Offline

snowfiled

Posts: 32

Re: how to plot op parameter curve in hspice?
Reply #4 - Apr 22^nd, 2005, 7:22am

Here is an example from Hspice user-guide

MOS I-V and C-V Plot Example Input File
*FILE: MOSIVCV.SP IDS, VGS, CV AND GM PLOTS
.OPTION SCALE=1U DCCAP
.DC VDDN 0 5.0 .1 $VBBN 0 -3 -3 sweep supplies
.PARAM ww=8 LL=2
$ ids-vds curves
.GRAPH 'I_VG=1' =I(MN1) 'I_VG=2' =I(MN2) 'I_VG=3' =I(MN3)
+ 'I_VG=4' =I(MN4)
.GRAPH 'I_VG=-1'=I(MP1) 'I_VG=-2'=I(MP2) 'I_VG=-3'=I(MP3)
+ 'I_VG=-4'=I(MP4)
$ ids-VGs curves
.GRAPH 'I_VD=.5'=I(MN6) 'I_VD=-.5'=I(MP6)
$ gate caps (cgs+cgd+cgb)
.GRAPH 'CG-TOT_N'=LX18(MN6) 'CG-TOT_P'= LX18(MP6)
$ gm
.GRAPH 'GM_N'=LX7(MN6) 'GM_P'=LX7(MP6)
VDDN vdd_n gnd 5.0
VBBN vbb_n gnd 0.0
EPD vdd_p gnd vdd_n gnd -1 $ reflect vdd for P devices
EPB vbb_p gnd vbb_n gnd -1 $ reflect vbb for P devices
V1 vg1 gnd 1
V2 vg2 gnd 2
V3 vg3 gnd 3
V4 vg4 gnd 4
V5 vddlow_n gnd .5
V-1 vg-1 gnd -1
V-2 vg-2 gnd -2
V-3 vg-3 gnd -3
V-4 vg-4 gnd -4
V-5 vddlow_p gnd -.5
MN1 vdd_n vg1 gnd vbb_n N W=ww L=LL
MN2 vdd_n vg2 gnd vbb_n N W=ww L=LL
MN3 vdd_n vg3 gnd vbb_n N W=ww L=LL
MN4 vdd_n vg4 gnd vbb_n N W=ww L=LL
MP1 gnd vg-1 vdd_p vbb_p P W=ww L=LL
MP2 gnd vg-2 vdd_p vbb_p P W=ww L=LL
MP3 gnd vg-3 vdd_p vbb_p P W=ww L=LL
MP4 gnd vg-4 vdd_p vbb_p P W=ww L=LL
MN6 vddlow_n vdd_n gnd vbb_n N W=ww L=LL
MP6 gnd vdd_p vddlow_p vbb_p P W=ww L=LL
.MODEL N NMOS LEVEL=3 VTO=0.7 UO=500 KAPPA=.25 ETA=.01
+ THETA=.04 VMAX=2E5 NSUB=9E16 TOX=400 KP=30U GAMMA=1.5
+ PB=0.6 JS=.1M XJ=0.5U LD=0.1U NFS=1E11 NSS=2E10
+ RSH=80 CJ=.3M MJ=0.5 CJSW=.1N MJSW=0.3 acm=2 capop=4
.MODEL P PMOS LEVEL=3 VTO=-0.8 UO=150 KAPPA=.25 KP=15U
+ ETA=.015 THETA=.04 VMAX=5E4 NSUB=1.8E16 TOX=400 GAMMA=.67
+ PB=0.6 JS=.1M XJ=0.5U LD=0.15U NFS=1E11 NSS=2E10
+ RSH=80 CJ=.3M MJ=0.5 CJSW=.1N MJSW=0.3 acm=2 capop=4
.END

Back to top

James

IP Logged

microant

Junior Member

Offline

Posts: 16
China,SH

Re: how to plot op parameter curve in hspice?
Reply #5 - Apr 24^th, 2005, 7:51pm

thanks for James and Andrew, i have plot it! i use the .meas statement and the ac analysis to plot it.
**single MOS performance test
.PARAM vinp=1 ibias=1u vcc=5
.PARAM vg1=1 vd1=2
.OP all
.AC dec 2 100 1k sweep data=corner2
.DATA corner2
tem
-40
25
60
125
.ENDDATA
*** output
***AC small-param
.MEAS AC GM find lx7(MN1) at=1k
.MEAS AC GDS find lx8(MN1) at=1k
.MEAS AC GMB find lx9(MN1) at=1k
.MEAS AC VTH find lv9(MN1) at=1k
.MEAS AC VDSAT find lv10(MN1) at=1k

*** voltage
.MEAS AC VGS find lx2(MN1) at=1k

*** capacitance at each terminal

.MEAS AC Cgtot find lx18(MN1) at=1k
.MEAS AC Cgd find lx19(MN1) at=1k
.MEAS AC Cgs find lx20(MN1) at=1k
.MEAS AC Cbg find lx21(MN1) at=1k
.MEAS AC Cbd find lx22(MN1) at=1k
.MEAS AC Cbs find lx23(MN1) at=1k
.MEAS AC Cdtot find lx33(MN1) at=1k
.MEAS AC Cdg find lx32(MN1) at=1k
.MEAS AC Cds find lx34(MN1) at=1k
.MEAS AC Cstot param='-Cgs-Cbs-Cds'
.MEAS AC Cbtot param='-Cbg-Cbs-Cbd'

*** netlist ***
MN1 VD1 VG1 0 0 nch l=4u w=2u m=1
MN2 VG2 VG2 0 0 nch l=4u w=2u m=1
I1 VCC VG2 dc ibias
V1 VCC 0 dc vcc
VG1 VG1 0 dc vg1 ac 1
VD1 VD1 0 dc vd1

best regard
microant

Back to top

IP Logged