Hi,
 
 I used to run Cadence sim under SUN Unix environment. Recently, we get converted to Linux RedHat environment. Under SUN, for each cadence window, we can minimize the window into an icon(which has a small picture) and I can conveniently organize the icons at different parts of the screen. With Linux, it minimize window into a small bar and placed it fixed at the bottom of the screen (and I can't move it around). Either that or I can "shade" the window by rolling the window into its long terminal bar, which allows me  to move it around. However, the bar is huge, occupying alot of space and the picture info is very limited.
 I wonder if there are any Cadence user under Linux environment can have a convenient way to iconize the cadence window (e.g. waveform, ADE windows).

Thanks !
Richard

I have a SKILL script which list most of the Cadence Windows and allows me,
by hitting the key F8, to raise them in the foreground, even icons.

Bernd

Code:

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; $RCSfile: raiseWindowsPopUp.il,v $
;;
;; Function(s):	   BFraiseWindowsPopUp
;;
;; $Author: bernd $
;;
;; Creation Date:	 2001/31/01
;;
;; $Revision: 1.1 $
;;
;; Application:	   DFII
;;
;; SW Release:	    Testet in 5.1.41
;;
;; SKILL Lint:	    Passed
;;
;; Global Variable(s):  None
;;
;; Synopsis:		BFraiseWindowsPopUp( )
;;
;; Description:	  This function creates a dynamic popup menu which list all
;;			   currently open or iconified windows plus the LSW
;;			   if you hit the bindkey F8 in the applications
;;			   "Command Interpreter", "Layout", "Schematics" and "Symbol".
;;			   A selection of the menu item for a special window will
;;			   push this window in the foreground.
;;			   To load/evaluate this SKILL code:
;;			   CIW> load( "<path>/raiseWindowsPopUp.il" )
;;
;; Arguments:	     -
;;
;; Return Value:	  t/nil
;;
;; Example:		 BFraiseWindowsPopUp( )
;;
;; $Log: raiseWindowsPopUp.il,v $
;; Revision 1.1  2007/12/13 07:57:59  bernd
;; *** empty log message ***
;;
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

procedure( BFraiseWindowsPopUp( )
	let( ( t_windowName t_windowIconName t_isIcon l_windowList
		l_windowNameList t_callBack l_callBackList )


/* Creation of a list of currently opened or iconified windows */

l_windowList = setof( element
	foreach( mapcar w_wId hiGetWindowList( ) w_wId ) /* foreach */
	hiGetWindowName( element )
	) /* setof */

foreach( w_wId l_windowList
	t_windowName = hiGetWindowName( w_wId )

	if( hiGetWindowIconifyState( w_wId ) then
		t_isIcon = "(Icon)"
	else
		t_isIcon = ""
	)

	when( t_windowName && t_isIcon
		t_windowIconName = buildString(
					list( t_windowName t_isIcon )
					)

/* Creation of a list of callbacks for all currently opened or iconified windows
   raise window if open and deiconify window if icon */
	cond(
		( hiGetWindowIconifyState( w_wId )
			t_callBack = sprintf(
					nil
					"hiDeiconifyWindow( window( %d ))"
					w_wId->windowNum
					)
		)
		( t
			t_callBack = sprintf(
					nil
					"hiRaiseWindow( window( %d ))"
					w_wId->windowNum
					)
			)
		) /* cond */
		) /* when */

		l_windowNameList = cons( t_windowIconName l_windowNameList )
		l_callBackList = cons( t_callBack l_callBackList )
) /* foreach */

/* If the layout context file is loaded then add the LSW into the list of
   currently open windows and add the callbacks for the LSW in the list
   of callbacks
   Raise LSW if open and deiconify LSW if icon */

 when( isContextLoaded( "le" )
	cond(
		(
 		leIsLSWIconified( )
		l_windowNameList = cons( "LSW (Icon)" l_windowNameList )
		l_callBackList = cons( "leDeiconifyLSW( )" l_callBackList )
		)
		(
		leGetLSWBBox()
		l_windowNameList = cons( "LSW" l_windowNameList )
		l_callBackList = cons( "leRaiseLSW( )" l_callBackList )
		)
	) /* cond */
) /* when */


/* Creation and displaying the popup menu */
hiDisplayMenu(
	hiCreateSimpleMenu(
		'TrWindowsPopUpMenu
		"Windows"
			l_windowNameList
			l_callBackList
			) /* hiCreateSimpleMenu */
		) /* hiDisplayMenu */

) /* let */

) /* procedure */


/* Building the bindkeys for all usefull applications */
let( ( l_applicationList )

	l_applicationList = list(
				"Command Interpreter"
				"Layout"
				"Schematics"
				"Symbol"
				)

	foreach(  t_application l_applicationList
		hiSetBindKey( t_application "<Key>F8" "BfRaiseWindowsPopUp( )" )
		) /* foreach */
) /* let */