Designer’s Guide Community

oehmen

New Member

Offline

Posts: 3

Spectre results significantly vary with errpreset
Jun 07^th, 2006, 9:40am

I have some trouble simulating a transformer.

I have simulated a transformer with different errpresets.
Input to the transformer is pulse source.
After switching, the output shows some rf-oscillations before it settles.
These oscillations strongly depend on the errpreset.

Using errpreset=liberal comes closest to measurements!
Moderate or conservative yields in a low attenuation of the rf-oscillations, whereas liberal yields in a short overshoot -just as measured!

I expected conservative to be as most accurate.
So, I am losing faith in simulation ...

Do I need to apply some tricks for this special case or for transformers at all?

I would be very grateful, if someone could share his experience with me.

Below is the netlist.

Many thanks,
Joerg

// Function generator
Vin (IN 0) vsource type=pulse val0=10 val1=-10 period=20e-6 width=10e-6 rise=1e-8 fall=1e-8
Rin (IN P1) resistor r=50
Rgen (P1 0) resistor r=50

// Transformer
Lleak1 (P1 P1a) inductor l=3.5e-6
Lmag (P1a 0) inductor l=3.27e-3
T_1 (P1a 0 S1a S2) transformer n1=40 n2=40 m=1
Lleak2 (S1a S1) inductor l=3.5e-6
Cwind (0 S2) capacitor c=225e-12
Rwind (0 S2) resistor r=100e6

// passive probe
Cprobe (S1 S2) capacitor c=7e-12

Diff (vdiff 0 S1 S2) vcvs gain=1

//simOptions options diagnose=yes rawfmt=psfascii rawfile="results" pivotdc=yes pivrel=0.5
saveOptions options save=all currents=all
tran tran start=0n stop=100e-6 errpreset=liberal

Back to top

IP Logged

bernd

Senior Member

Offline

Posts: 229
Munich/Germany

Re: Spectre results significantly vary with errpre
Reply #1 - Jun 8^th, 2006, 1:23am

The errpreset has set the integration method and other
parameters for you analysis, this can have a influence on
how your circuit simulation behaves.

Refer to the docs:
Spectre Circuit Simulator User Guide
Spectre Circuit Simulator Reference -- 3. Analysis Statements

Or probably buy Kens Book - The Designer's Guide to SPICE and Spectre
http://www.designers-guide.org/Books/

Bernd

Back to top

Just another lonesome cad guy

IP Logged

oehmen

New Member

Offline

Posts: 3

Re: Spectre results significantly vary with errpre
Reply #2 - Jun 8^th, 2006, 3:02am

Thank you for the answer, Bernd. I know, that it sets the integration method and I have checked each method. I have been quite surprised, that the results differ that much.

That raises the question, which method can I trust and which not? If I design a converter, do I have to do something against these rf-oscillations or not? Are these oscillations are real or just fictitious?

Which are the right parameter settings for the simulation? Usually, errpreset=conservative should results in an higher accuracy, right?

I would be very grateful for further comments on this topic!

Many thanks,
Joerg

Back to top

IP Logged

sheldon

Community Fellow

Offline

Posts: 751

Re: Spectre results significantly vary with errpre
Reply #3 - Jun 8^th, 2006, 5:16am

Jeorg,

Are you sure that your transformer model is correct? Here is a slightly modified
version of the transformer model. The winding resistance is now in series with the
leakage inductance and the winding capacitance shunts the secondary. Also, the
probe resistance and the primary resistance and capacitance have been added.

The other comment is that the moderate error preset uses trap integration and
is susceptable to ringing. You can use the moderate preset with gear2only
integration and get good results, see the attachment.

Best Regards,

Sheldon

// Function generator
Vin (IN 0) vsource type=pulse val0=10 val1=-10 period=20e-6 width=10e-6 rise=1e-8 fall=1e-8
Rin (IN P1) resistor r=50
Rgen (P1 0) resistor r=50

// Transformer
Rwindp (P1 P1b) resistor r=0.01
Lleak1 (P1b P1a) inductor l=3.5e-6
Cwindp (P1a 0) capacitor c=225p
Lmag (P1a 0) inductor l=3.27e-3
T_1 (P1a 0 S1a S2) transformer n1=40 n2=40 m=1
Lleak2 (S1 S1b) inductor l=3.5e-6
Cwind (S1a S2) capacitor c=225e-12
Rwind (S1a S1b) resistor r=0.01

// passive probe
Cprobe (S1 S2) capacitor c=7e-12
Rload ( S1 S2) resistor r=10M

Rdummy (S2 0) resistor r=10G

Diff (vdiff 0 S1 S2) vcvs gain=1

//simOptions options diagnose=yes rawfmt=psfascii rawfile="results" pivotdc=yes pivrel=0.5
saveOptions options save=all currents=all
tran tran start=0n stop=100e-6 errpreset=moderate method=gear2only step=100n

Back to top

IP Logged

sheldon Community Fellow Offline Posts: 751	Re: Spectre results significantly vary with errpre Reply #4 - Jun 8^th, 2006, 5:18am Having some trouble attaching
Back to top	xfrmr.png IP Logged

oehmen

New Member

Offline

Posts: 3

Re: Spectre results significantly vary with errpre
Reply #5 - Jun 19^th, 2006, 9:01am

Thank you, Sheldon!

The transformer model should be correct (the capacitance has been measured between primary and secondary side). Due to the trifilar winding, the interwinding capacitance should be very low.
Furthermore, I have omitted the resistances as the impact on simulation results is quite low.

But indeed, your simulation results look like my measurements.
The differences in your simulation results are quite low compared to my simulation results.
Up to now, I have not been able to measure the interwinding capacitance as I did not find any resonance frequency. These capacitance seems to be the key for a successful simulation.

Hence, I will take a closer look at the transformer model. Wish, it would be easier to get all these transformer's parasites.

What stays is, that I will feel quite unconfident about simulation results when simulating circuits with large inductances and I will check all integration methods and errpresets.

Many thanks,
Joerg

Back to top

IP Logged