Hey I've got a question about how the TLine model works in Spectre.

I specify Zo=50 and Td=10ns

I am checking things out however, at DC.

The symbol looks something like this

   a-----xxxxxxxxxxxx-------b
   c-----xxxxxxxxxxxx-------d


At DC,   shouldn't   a and b actually be connected to each other- and not to c/d?

and shouldn't   c and d actually be connected to each other and not to a/b?


This is not how things are looking actually...   and it is puzzling to me.  I guess I have never looked at tline behavior before at DC but now I need too...


thoughts?

The tline model in Spectre and SPICE is perfectly happy having different DC voltages on the outer conductors at both ends of the lines.

Let
     Vi1 = voltage on inner conductor of port 1
     Vo1 = voltage on outer conductor of port 1
     Vi2 = voltage on inner conductor of port 2
     Vo2 = voltage on outer conductor of port 2
Then in DC the transmission line enforces that
     Vi1 - Vo1 = Vi1 - Vo2
In other words it models the odd mode, which is RF jargon for the differential mode.  It allows Vo1 != Vo2, which means it is not modeling the even mode (or the common mode).

To model both even and odd modes in a coax configuration, use the following subcircuit (note that this model is non-symmetric).

subckt coax (i1 o1 i2 o2)
   parameters zinner=50 zouter=50 vinner=1 vouter=1 td=1
   inner i1 o1 i2 o2  tline z0=zinner vel=vinner td=td
   outer o1 0  o2 0   tline z0=zouter vel=vouter td=td
ends coax

To model both even and odd modes in a twisted-pair configuration, use the following subcircuit (note that this model is symmetric).

subckt twisted (p1 n1 p2 n2)
   parameters zodd=50 zeven=50 veven=1 vodd=1 td=1
   odd  p1 n1 p2 n2  tline z0=zodd vel=vodd td=td
   tf1a p1 0  e1 c1  transformer t1=2 t2=1
   tf1b n1 0  c1 0   transformer t1=2 t2=1
   even e1 0  e2 0   tline z0=zeven vel=veven td=td
   tf2a p2 0  e2 c2  transformer t1=2 t2=1
   tf2b n2 0  c2 0   transformer t1=2 t2=1
ends twisted

-Ken